'METASTOCK DATA BY cophieu68.vn
'2024 by cophieu68.vn

Dim objFSO, objHTTP, stream , objShell, importFormat, echoStr
Set objHTTP  = CreateObject("WinHttp.WinHttpRequest.5.1")
Set objShell = CreateObject("Shell.Application")
set objFSO   = CreateObject("Scripting.FileSystemObject")
Set stream   = CreateObject("ADODB.Stream")

Dim DIR_PATH_DATA
'SUA DUONG DAN THU MUC LUU DATA TAI DONG DUOI... LUU Y CHI SUA TRONG DAU "" VI DU "D:\Metastock_CP68_Data"
DIR_PATH_DATA = "C:\Metastock_CP68_Data"

If ( Not objFSO.FolderExists(DIR_PATH_DATA) ) Then

	Dim Ans 'Answer
	message = "BAN CO MUON TAO THU MUC DU LIEU " & DIR_PATH_DATA
	Ans = Msgbox (message, vbYesNo)

	If Ans = vbYes Then
		Dim oFSO
		Set oFSO = CreateObject("Scripting.FileSystemObject")
		oFSO.CreateFolder DIR_PATH_DATA
	Else
		WScript.Echo( DIR_PATH_DATA & " # Thu muc khong ton tai. Vui long kiem tra va cap nhat lai duong dan tai dong 13 !!!" )
		WScript.Quit
	End If
End If

strLast = Right(DIR_PATH_DATA, 1)
If( strLast = "\"  ) Then
    intLength = Len(DIR_PATH_DATA)
    DIR_PATH_DATA = Left(DIR_PATH_DATA, intLength - 1)
End If



Call receiveAlert()
WScript.Sleep 5*1000
WScript.Quit

Sub receiveAlert()
	fileURL = "https://www.cophieu68.vn/download/_metastock.php?type=check"
    objHTTP.Open "GET", fileURL, False
    objHTTP.Send

	If ( objHTTP.responseText <> "" ) Then
		 WScript.Echo( objHTTP.responseText )
	Else
		Call ImportEOD()
	End If

    SET objHttp = Nothing

End Sub


Sub ImportEOD()
    WScript.Echo( "Dang ket noi du lieu den cophieu68.vn ..., vui long cho trong 30 giay." )
    'HTTPDownload
	fileURL = "https://www.cophieu68.vn/download/_metastock.php"
    objHTTP.Open "GET", fileURL, False
    objHTTP.Send


	'customize source file format
	fileNameZipDownload  = objFSO.GetAbsolutePathName(".") & "\metastock.zip"

    'write the downloaded byte stream to the target file
    stream.Open
    stream.Type = 1 'binary
    stream.Write objHTTP.ResponseBody
    stream.SaveToFile fileNameZipDownload , 2  'overwrite
    stream.Close

    'check files zip download
    SET objFile = objFSO.GetFile(fileNameZipDownload)
    If ( objFSO.FileExists(fileNameZipDownload) AND objFile.Size/1024 > 10 ) Then
        WScript.Echo( "Dang thuc hien cap nhat du lieu cho METASTOCK ..." )
        'unZip
        Set FilesInZip = objShell.NameSpace(fileNameZipDownload).items
        objShell.NameSpace(DIR_PATH_DATA).CopyHere(FilesInZip)
        objFSO.DeleteFile fileNameZipDownload

        WScript.Echo( "METASTOCK da cap nhat tat ca du lieu thanh cong: " & Now & vbCrLf )
    Else
       WScript.Echo("Du lieu download tu cophieu68.vn khong ton tai. Vui long kiem tra lai ket noi mang, hoac cophieu68 da nang cap phan mem cap nhat du lieu, vao trang http://www.cophieu68.vn de xem thong tin chi tiet.")
       WScript.Sleep 5*1000
       WScript.Quit
    End If
End Sub